#!/usr/bin/perl
# Number all house lots on all roads within given bounding box.
# Bounding box of course uses local house numbering coordinates.
# Author: Dan Jacobson https://www.jidanni.org/
# Copyright: https://www.gnu.org/licenses/gpl.html
# Created: 2026-08-22T07:10:46+0000
# Last-Updated: 2026-08-23T23:44:26+0000
#     Update #: 29
#
use strict;
use warnings q(all);
use integer;
if ( @ARGV != 5 ) {
    die <<EOF;
Usage: $0 edge range1_min range1_max range2_min range2_max, E.g.
\$ $0 1000 4200 4400 700 800
which means number all house plots on blocks 4200, 4300, and 4400
and spanning blocks 700 and 800, using 1000 as the divider to tell if we are talking
about horizontal roads or vertical roads.
Warning, even just
\$ $0 1000 4200 4200 700 700 will give about 200 numbers.
EOF
}
my $block   = $ENV{block}   || 100;
my $setback = $ENV{setback} || $block / 50;
my $edge    = $ARGV[0];
for ( @ARGV[ 1 .. 4 ] ) {
    die "$_ is not a multiple of $block." if $_ % $block;
    $_ /= $block;
}
my @block_range =
  ( [ $ARGV[1] .. $ARGV[2] ], [ $ARGV[3] .. $ARGV[4] ] );
printf "x,y,zh,en$/";
for ( 0, 1 ) {
    for my $p ( @{ $block_range[$_] } ) {
        for my $q ( @{ $block_range[ !$_ ] } ) { n( $p, $q ) }
    }
}

sub n {
    for my $r ( 2 .. 48 ) {
        for my $s ( 0 .. 1 ) {
            my $road        = $_[0] * $block;
            my $housenumber = $_[1] * $block + $r * 2 + $s;
            my @coordinates;
            for ( $road + $setback * ( $s ? 1 : -1 ), $housenumber ) {
                $coordinates[ $_ <= $edge ] = $_;
            }
            for ( 0, 1 ) {
                die "Not respecting the need for both sides of edge?"
                  unless $coordinates[$_];
            }
            printf "%d,%d,%d路%d號,No. %d Rd. %d$/",
              @coordinates, ( $road, $housenumber ) x 2;
        }
    }
}